Chicken'z blog

Pour connecter un contrôleur midi à un synthétiseur, il faut pouvoir gérer efficacement plusieurs voix en parallèle, ce qui n'est pas trivial avec un système de threading basique. J'ai tenté d'implémenter un synthétiseur commandé par mon contrôleur MIDI, donc, et le résultat est assez concluant.

La première partie explique la théorie des événements chuck, et je commenterai le code dans la seconde partie.

La théorie

Si vous ne connaissez pas MIDI, il s'agit d'un protocole très simple pour partager des notes de musique et des commandes entre plusieurs instruments, et des ordinateurs. L'utilisateur appuie sur une touche de son clavier avec une certaine vélocité, et ces paramètres sont envoyés par le port MIDI.

Ensuite, un oscillateur à la bonne fréquence est branché à la sortie, avec le bon gain (le volume, modulé en fonction de la pression sur la touche). Tout ceci est fort amusant jusqu'à ce que l'utilisateur désire appuyer sur deux touches en même temps.

Ma première approche à été de créer un oscillateur et une enveloppe pour chaque note. L'enveloppe d'un son est, en gros, l'évolution de son volume au cours du temps.

Lorsqu'une note est reçue par le manager, un thread est lancé et s'occupe soit d'activer la bonne note, soit de la désactiver, en utilisant pour cela une sorte de pile FIFO.

Cette méthode fonctionnait, mais j'ai tout de même dû ajouter un thread de vérification. En effet, certains événements noteOff étaient ignorés ou perdus.

Ensuite, j'ai découvert dans les exemples de chuck une méthode bien meilleure :

Au début, un nombre N de threads sont crées, et attendent chacun un événement. Lorsqu'une note est reçue, le manager déclenche l'événement pour un unique thread (le premier dans la liste). Celui-ci va connecter un oscillateur à la sortie et déclencher la note, puis attendre l'événement signalant la fin de la note. Quand le manager reçoit une fin de note, il déclenche l'événement correspondant à cette note dans un tableau, qui est réceptionnée par le bon thread.

Implémentation

Cette partie peut nécessiter quelques notions de ChucK, mais le langage est plutôt compréhensible. Le code coloré avec pygments et donc à peu près lisible se trouve ici.

Initialisation

class NoteEvent extends Event {
    // Cette classe crée des événements contenant quelques données
    // additionnelles
    int note;
    int velocity;
}

NoteEvent on;

// Création d'un tableau d'événements
// Ces événements seront déclenchés à chaque note relâchée
// Le "@" permet de créer des références vides, c'est-à-dire de ne rien
//  instancier pour le moment. Les threads se chargeront de cela
Event @ keys[128];

// On connecte un gain à la sortie audio
// Tous les oscillateurs y seront connectés
Gain g => dac;

Une voix

fun void voice() {
    // On applique une enveloppe à l'oscillateur qui sera connecté à la sortie
    SinOsc s => ADSR a;
    // On fixe les rampes de l'enveloppe
    a.set(10::ms, 100::ms, .3, 500::ms);
    // L'événement qui servira à récupérer la fin de la note
    Event off;
    // Les codes de la note et de la vélocité (0 - 127)
    int note;
    int vel;

    while (true) {
        // Cette ligne permet d'attendre que l'événement soit déclenché
        on => now;

        // L'événement contient deux valeurs : la note et sa vélocité
        on.note => note;
        on.velocity => vel;

        vel / 128.0 => s.gain;
        // La fonction mtof convertit une note MIDI en une fréquence
        Std.mtof(note) => s.freq;

        // Connexion de l'enveloppe au gain principal
        a => g;
        // Début de la note
        // Elle sera maintenue jusqu'à ce qu'on utilise explicitement la méthode
        //  keyOff()
        a.keyOn();

        // On place l'événement off spécifique à ce thread à la bonne place dans
        //  le tableau. Ainsi, le manager pourra y accéder.
        off @=> keys[note];
        // Puis on attend.
        off => now;
        // Lorsque la note est terminée, on replace la référence vide dans le
        //  tableau
        null @=> keys[note];

        a.keyOff();
        // On déconnecte la sortie
        a =< g;
    }
}

Le manager

// On crée vingt threads
for (0 => int i; i < 20; i++)
    spork ~ voice();

// On tente d'ouvrir une connexion à un périphérique MIDI
MidiIn mid;
MidiMsg msg;
if (!mid.open(0))
    me.exit();

while (true) {
    // MidiIn est un événement, on va donc simplement attendre
    mid => now;
    // À la réception d'un message, il est analysé
    while (mid.recv(msg)) {
        // Seul noteon est intéressant ici, le reste est donc rejeté.
        if (msg.data1 != 144)
            continue;

        if (msg.data3 > 0) {
            // Si la vélocité est supérieure à 0, la note est appuyée
            msg.data2 => on.note;
            msg.data3 => on.velocity;

            // La méthode signal() déclenche l'événement pour le premier
            //  shred en attente uniquement (au contraire de la méthode
            //  broadcast())
            on.signal();

            // On permet ensuite au shred de tourner sans avancer le temps
            //  dans le shred courant
            me.yield();

        } else {
            // Sinon, cela signifie que la note est relâchée
            // On déclenche donc l'événement 'off' correspondant
            if (keys[msg.data2] != null)
                keys[msg.data2].signal();
        }
    }
}

La suite

Je compte déjà permettre plusieurs oscillateurs par voix, avec la possibilité de synchronisation et de ring modulation, puis d'associer chaque paramètre à des potentiomètres ou des curseurs (dès que j'aurai un meilleur clavier maître). Si vous êtes intéressé, suivez l'activité sur mon dépôt.

Chose promise, chose due. Dans le cadre d'un test de javascript laid+cgi, et surtout pour le lulz, j'ai ajouté un module super communautaire pour me rapprocher de mes fans. Eh ouais, regardez donc là en-bas, le petit bouton.

Si vous connaissez sur le bout des doigts vos machins de blogging trop hype, vous aurez certainement reconnu ceci. Ce n'est évidemment pas en relation avec facebook, tout est stocké ici-même.
Voilà, l'utilité est à peu près du même ordre que celle de la banane volante sur ma page d'accueil, mais ça m'amusait.

Unleash your apathy!

Ouais donc j'ai décidé d'écrire un peu plus dans mon blog, même quand je fais des scripts insignifiants. Parce que maintenant, j'ai un moteur de blog qui fonctionne ! Yeah. Et pas de commentaires, parce que bon, pas envie. Pour me contacter, voyez la page contact à droite.

Au menu aujourd'hui, un script permettant de récupérer des flux RSS (ouais ou atom gnagna.) et de lancer des commandes pour tout nouvel élément. Au lieu de bricoler quarante scripts et de bidouiller crontab, pouf on centralise le tout dans un joli fichier de conf. Ça existe probablement déjà en mieux, mais mes trente secondes de recherche n'ont mené à rien.

La configuration est plutôt simple, c'est du python alors c'est joli et facile à comprendre.

from monmodulegenial import mafonctiontropcool

delay = 30 # minutes
cache = "/home/Leia/.cache/rssblah"
verbose = False

sites = (
    ("http://site1.bla/feed.xml", "/home/Leia/scripts/site1.sh"),
    ("http://sit2...", "/usr/bin/perl /home/Leia/foo.pl", {"args": (lambda e:
            e.link)})
    ("http://site2...", mafonctiontropcool, {"once": True})
)

Une explication pour les arguments : cela peut être soit une liste ou une chaîne, soit une fonction qui prend un élément en argument. J'utilise universal feedparser pour gérer les flux, donc il s'agit d'une entry

Ensuite, on lance le script, éventuellement avec un nohup parce que c'est la vie. La configuration est relue à chaque fois, donc on n'a pas à se soucier du process, en théorie.

Ici, le code

Voici donc ma dernière merveille, un script permettant d'écrire du texte brut sans se soucier de la largeur et l'alignement.
Il a surtout été motivé par ma feignantise chronique et répond en fait à plusieurs besoins:

• ne pas s'occuper de la largeur du texte que l'on écrit tout en limitant le nombre de colonnes (un bon éditeur de texte se charge normalement de cela),
• ne pas s'occuper de l'alignement, du centrage,
• ne pas se soucier de la numérotation des sections et titres,

Mon script est capable pour l'instant de créer des marges, de centrer, de gérer les listes numérotées ainsi que les titres sur différents niveaux, et enfin d'ajouter un sommaire.

La syntaxe devait être la plus simple possible, pas de xml, pas de signes bizarres ({}<>/). Puisqu'il s'agit de texte brut, les possibilités offertes par le langage seront très limitée, et le nombre de mots-clés faible. Nul besoin, donc, de commandes du type \begin{bloc} \end{bloc}.
Pour la même raison, pas question non plus de récupérer la syntaxe des langages de balisage léger existants, puisque leur but est surtout le formatage au niveau du texte, et non au niveau des blocs.
La priorité est l'écriture du texte, et surtout pas le rendu final, j'ai donc choisi une syntaxe par blocs, définie ainsi:

␣␣␣␣instruction [arguments]
texte
texte
...
␣␣␣␣instruction [arguments]
texte
...

Une instruction est précédée d'au minimum trois espaces ou une tabulation. Pour l'instant, les commandes disponibles sont :

• title niveau titre
• margin taille, rmargin taille, lmargin taille, margin gauche droite
• list [mode] mode peut être a, i, I, 1 suivi de signes quelconques, ou vide. Par exemple list a) produira a), b), c)…
• center.

Il manque encore un système de références/bibliographie avec une syntaxe inline du genre ((référence)) ou [[référence]]. Puisqu'il n'y a pas de pagination ni de différence de style, je ne pense pas ajouter de notes de bas de page.

Pour l'instant, les options ne peuvent pas être passées dans la commande, elles sont placées au début du script. Ça viendra.

Voici un exemple de texte en entrée (qui est moins repoussant dans une console.):

    center

BLAH 

    plain
Intro moche : Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Sed non risus. Suspendisse lectus tortor, dignissim sit amet, adipiscing nec, ultricies sed, dolor.

    margin 5
Sommaire :

{{SUMMARY}}

    title 1 Cras elementum ultrices diam. Cras elementum ultrices diam Cras elementum ultrices diam Cras elementum ultrices diam Cras elementum ultrices diam

Maecenas ligula massa, varius a, semper congue, euismod non, mi. Proin porttitor, orci nec nonummy molestie, enim est eleifend mi, non fermentum diam nisl sit amet erat. Duis semper.

    title 2 Duis arcu massa, scelerisque vitae.

consequat in, pretium a, enim. Pellentesque congue. Ut in risus volutpat libero pharetra tempor. Cras vestibulum bibendum augue.

    title 2 Praesent egestas leo in pede.

Praesent blandit odio eu enim. Pellentesque sed dui ut augue blandit sodales. Vestibulum ante ipsum primis in faucibus orci luctus et ultrices posuere cubilia Curae;

    title 1 Aliquam nibh.
    title 2 Mauris ac mauris sed pede pellentesque fermentum.

Maecenas adipiscing ante non diam sodales hendrerit. Ut velit mauris, egestas sed, gravida nec, ornare ut, mi.

    margin 40 20
Aenean ut orci vel massa suscipit pulvinar. Nulla sollicitudin. Fusce varius, ligula non tempus aliquam, nunc turpis ullamcorper nibh, in tempus sapien eros vitae ligula.
Pellentesque rhoncus nunc et augue. Integer id felis. Curabitur aliquet pellentesque diam.

   title 3 Integer quis metus

vitae elit lobortis egestas. Lorem ipsum dolor sit amet, consectetuer adipiscing elit.

    title 3 Morbi vel erat non mauris convallis vehicula.

Nulla et sapien. Integer tortor tellus, aliquam faucibus, convallis id, congue eu, quam. Mauris ullamcorper felis vitae erat. Proin feugiat, augue non elementum posuere, metus purus iaculis lectus, et tristique ligula justo vitae magna.

    title 2 Aliquam convallis sollicitudin purus.

Proin feugiat, augue non elementum posuere, metus purus iaculis lectus, et tristique ligula justo vitae magna.

    list a.
  - Praesent aliquam, enim at
  - fermentum mollis, ligula massa adipiscing nisl,
  - ac euismod nibh nisl eu lectus. Fusce vulputate sem at sapien.
  Vivamus leo.
  - Aliquam euismod libero eu enim.

    plain

Nulla nec felis sed leo placerat imperdiet.

    title 2 Aenean suscipit nulla in justo. Suspendisse cursus rutrum augue. Nulla tincidunt tincidunt mi.

Curabitur iaculis, lorem vel rhoncus faucibus, felis magna fermentum augue, et ultricies lacus lorem varius purus. Curabitur eu amet.

Et la sortie :

                                                                               
                                      BLAH                                      

Intro moche : Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Sed non
risus. Suspendisse lectus tortor, dignissim sit amet, adipiscing nec, ultricies
sed, dolor.

     Sommaire :  
      I.      Cras elementum ultrices diam. Cras elementum ultrices diam Cras
              elementum ultrices diam Cras elementum ultrices diam Cras
              elementum ultrices diam
      I.1.    Duis arcu massa, scelerisque vitae.
      I.2.    Praesent egestas leo in pede.
      II.     Aliquam nibh.
      II.1.   Mauris ac mauris sed pede pellentesque fermentum.
      II.1.a) Integer quis metus
      II.1.b) Morbi vel erat non mauris convallis vehicula.
      II.2.   Aliquam convallis sollicitudin purus.
      II.3.   Aenean suscipit nulla in justo. Suspendisse cursus rutrum augue.
              Nulla tincidunt tincidunt mi.

  I. Cras elementum ultrices diam. Cras elementum ultrices diam Cras elementum
     ultrices diam Cras elementum ultrices diam Cras elementum ultrices diam

Maecenas ligula massa, varius a, semper congue, euismod non, mi. Proin
porttitor, orci nec nonummy molestie, enim est eleifend mi, non fermentum diam
nisl sit amet erat. Duis semper.

    1. Duis arcu massa, scelerisque vitae.

consequat in, pretium a, enim. Pellentesque congue. Ut in risus volutpat libero
pharetra tempor. Cras vestibulum bibendum augue.

    2. Praesent egestas leo in pede.

Praesent blandit odio eu enim. Pellentesque sed dui ut augue blandit sodales.
Vestibulum ante ipsum primis in faucibus orci luctus et ultrices posuere cubilia
Curae;

  II. Aliquam nibh.

    1. Mauris ac mauris sed pede pellentesque fermentum.

Maecenas adipiscing ante non diam sodales hendrerit. Ut velit mauris, egestas
sed, gravida nec, ornare ut, mi.
                                        Aenean ut orci vel
                                        massa suscipit
                                        pulvinar. Nulla
                                        sollicitudin. Fusce
                                        varius, ligula non
                                        tempus aliquam, nunc
                                        turpis ullamcorper
                                        nibh, in tempus
                                        sapien eros vitae
                                        ligula. Pellentesque
                                        rhoncus nunc et
                                        augue. Integer id
                                        felis. Curabitur
                                        aliquet pellentesque
                                        diam.
      a) Integer quis metus

vitae elit lobortis egestas. Lorem ipsum dolor sit amet, consectetuer adipiscing
elit.

      b) Morbi vel erat non mauris convallis vehicula.

Nulla et sapien. Integer tortor tellus, aliquam faucibus, convallis id, congue
eu, quam. Mauris ullamcorper felis vitae erat. Proin feugiat, augue non
elementum posuere, metus purus iaculis lectus, et tristique ligula justo vitae
magna.

    2. Aliquam convallis sollicitudin purus.

Proin feugiat, augue non elementum posuere, metus purus iaculis lectus, et
tristique ligula justo vitae magna.

  a. Praesent aliquam, enim at
  b. fermentum mollis, ligula massa adipiscing nisl,
  c. ac euismod nibh nisl eu lectus. Fusce vulputate sem at sapien.   Vivamus
     leo.
  d. Aliquam euismod libero eu enim.

Nulla nec felis sed leo placerat imperdiet.

    3. Aenean suscipit nulla in justo. Suspendisse cursus rutrum augue. Nulla
       tincidunt tincidunt mi.

Curabitur iaculis, lorem vel rhoncus faucibus, felis magna fermentum augue, et
ultricies lacus lorem varius purus. Curabitur eu amet.

Et le script se trouve ici. [Commentaires](http://buzzerl.iuwt.fr/web/link?id=231)

Chuck est un langage de programmation à la syntaxe proche du C permettant la synthèse audio, la composition et l’analyse du son. Rien que ça. Il est plutôt simple à prendre en main, et peu s’avérer très puissant.

Voici mon premier essai, rien de plus qu’un peu de bruit :

PulseOsc p => dac => WvOut w => blackhole;
"/tmp/dump.wav" => string filename => w.wavFilename;


20 => p.freq;
.7 => p.width;
.01 => p.phase;

fun void beat1 (float s, float e, float l) {
    1 => int sign;
    s => p.freq;
    if (e < s) {
        s => float t; e => s; t => e;
        -1 => sign;
    }
    (e - s) / l => float stp;
    <<< "Start:", s, "  End:", e, "  Step:", stp, "  Sign:", sign >>>;
    for (s => float i; i < e; i + stp => i) {
        p.freq() + (sign * stp) => p.freq;
        1::ms => now;
    }
}

for (.5 => float b; b > 0.01; b - 0.01 => b) {
    beat1(420, 20, 500.0 * b);
}

for (50 => int i; i < 200 ; i++) {
  beat1(80, 22, 200);
  22 => int j;
  while (j < 550) {
    beat1(j, j + 100, 90);
    j + 20 => j;
  }
  beat1(550, 22, 200);
  (p.width() + 0.1) % 0.9 => p.width;
  <<< "Pwet." >>>;
}

Le résultat est là : crap.wav

Avec un peu d’entraînement, il doit être possible de faire du son écoutable, et même de la musique (!!). Gonna be fun.